; hnhbref.bv
; 2D 15N-1H reference spectrum for quantitation
; of 3J(15N-1Hbeta)from 3D HNHB spectrum
; States-TPPI in t1
; Bax et al., Methods Enz. 239, 79 (1994)
; Bruker DMX Avance, XwinNMR version
; implemented by Brian Volkman, volkman@nmrfam.wisc.edu
; last modified 10/5/95 BFV
;BMRB Pulse Sequence Accession Number: 25

; d4 = 2.25m
; d5=27m
; d6=27m
; d11 = delay for disk I/O = 30m
; d12 = delay for power switching = 20u
; d13 = short delay = 3u
"d16=d0+p1*2"
"d29=p2-p1"

; pl1 = transmiter high power for 1H
; pl2 = 15N high power
; pl9 = transmiter power level for presaturation

; l3 = number of complex points in t1
; in0 = increment t1 (d0)  = (dwell in t1)/2

1 d11 ze        
2 d11           
3 d11
   d11*2        
4 d12 pl9:f1  
  d12 do:f2             ; decoupler off
  d12 pl2:f2    
  (p18 ph29):f1 ; presaturation during relaxation delay
  d13           
  d12 pl1:f1    
;
; *** INEPT ***
;
  (p1 ph0):f1   ; p1 = 90 H1 puls
  (p21 ph10):f1 ; spin lock
  d4 cpd3:f3 ; cpd4:f4         
  (d29 p1*2 ph0):f1 (p2*2 ph1):f2  
  d4
  (p22 ph0):f1 ; spin lock
  (p1 ph1):f1 (p2 ph4):f2
;
; *** 15N evolution (t1) ***
;
  d0            ;
  (p1*2 ph0):f1
  d5
  (p2*2 ph3):f2
  d6
  d16
;
; *** Reverse INEPT ***
;
  (d29 p1 ph0):f1 (p2 ph0):f2
  d4
  5u
  (d29 p1*2 ph0):f1 (p2*2 ph0):f2
  d4 pl16:f2 
  5u
  (p1 ph0):f1
  go=2 ph31 cpd2:f2
  d11 wr #0 do:f2 if #0 ip4 zd  
  lo to 3 times 2       
  d11 ip31*2 
  d11 id0   
  d11 dd6
  lo to 4 times l3      
exit

ph29=0
ph0=0
ph1=1 3
ph2=0 0 0 0 0 0 0 0
ph3=0 0 1 1 2 2 3 3  
ph4=0
ph7=3
ph10=1
ph31=0 2 2 0 0 2 2 0